[#Part: CMP TallyShopFeatures Left]
	add    : line      :  EnableSignatureInInvoice

[line :   EnableSignatureInInvoice]
	field : medium prompt,   EnableSignatureInInvoice
	Local : field : medium Prompt : Set as  :"Enable Seal & Signature In Voucher Printing ?"
    Local : field : medium Prompt : Width : 35
	space top :  2 mm

	field : Long prompt
	Local : field : Long Prompt : Set as  	: "(Note : Set Seal & Signature Image Path In Voucher Type Level)"
    Local : field : Long Prompt : Width 	: 45
	Local : field : Long Prompt : Align		: Centre
	Local : field : Long Prompt : Style		: Small Bold Italic
	Local : field : Long Prompt : Color		: Blue
	Local : field : Long Prompt : Full Width:Yes
	Local : field : Long Prompt : Inactive : NOT $EnableSignatureInInvoice
	
[field :  EnableSignatureInInvoice]
	Use : Logical Field 
	Storage :   EnableSignatureInInvoice


[#Part: EXPINV Customer]
	Add:Option: InvoiceCustomer_RightSignv : @@CMP_SignatureInInvoice
	
[!Part:InvoiceCustomer_RightSignv]
	Left Parts  : EXPINV CustomerSign
	delete		: Right Parts : EXPINV Signature
	Option      : Small Size Part
	Border      : Thin Box
	Vertical    : No
	
	Invisible   : NOT ##SACustomerSign
	
	Local		: Part : EXPINV Signature	 : Delete: Border
	Local		: Part : EXPINV Signature 	 : Border: ThinLeft

	Add			: Right Parts:At End:Vaibhav_Signature
	Local		: Part:Vaibhav_Signature : Invisible   : not ##SACustomerSign
					
[#Form: GST Comprehensive Invoice Default]
	Add:Option: vInvoiceCustomer_RightSignv : @@CMP_SignatureInInvoice
	
[!Form:vInvoiceCustomer_RightSignv]    
	Local : Part : EXPINV SignOff       : delete:Height	
    Local : Part : EXPINV MainSignOff   : delete:Height    
    			
[#Part: EXPINV RightSign]
	Add:Option: cvInvoiceCustomer_RightSignv : @@CMP_SignatureInInvoice
	
[!Part:cvInvoiceCustomer_RightSignv]
	Delete: Bottom Part: EXPINV Signature
	Delete:BottomParts : EXPINV LBT Details, EXPINV DateTime, EXPINV Signature
	Delete:Part        : EXPINV ExciseDetails

	Add: Bottom Part: At End: Vaibhav_Signature
	Local:Part:Vaibhav_Signature : Invisible   : ##SACustomerSign
			
[Part:Vaibhav_Signature_01]
	 Line        : EXPSMP Signature 01 
	 Border  	:  Full Thin Top
	 Space Bottom: .3
	 
[Line: EXPSMP Signature 01]
     PrePrinted  : Yes

     Right Fields    : Simple Field

	 Local			: Field : Simple Field : Set as : If NOT ($$IsSysNameEqual:Primary:##SVAddressToPrint OR $$IsEmpty:##SVAddressToPrint) Then +
																	If NOT $$IsEmpty:@@InvoiceCmpNameAddrType Then +
																		$$Sprintf:@@CompanyMailFormat:@@InvoiceCmpNameAddrType +
																	Else +
																		"" +
																  Else +
																	If NOT $$IsEmpty:@@InvoiceCmpName Then +
																		$$Sprintf:@@CompanyMailFormat:@@InvoiceCmpName +
																	Else +
																		""

	Local           : Field : Simple Field : Style  : Normal Bold
	Local           : Field : Simple Field : Cell   :  @@ExcelCellColumn - 6 * ($$Quotient:@@ExcelCellColumn:8)
	Local           : Field : Simple Field : Align  : Left
	
[Line:Vaibhav_Signature_02]
	RightField:Vaibhav_Signature_02
	
[Field:Vaibhav_Signature_02]
	Set as:""

[Part:Vaibhav_Signature_03]
	Bottom Lines: EXPSMP Authourity 03
	
[Line: EXPSMP Authourity 03]

	Left Fields		: Name Field,Short Name Field
    Right Fields    : Simple Field

    Local           : Field : Name Field : Set as 		: $$LocaleString:"Prepared by"
    Local           : Field : Name Field : Style  		: Small
	Local           : Field : Name Field : Cells  		: @@ExcelCellColumn - 12 * ($$Quotient:@@ExcelCellColumn:8)  
	Local           : Field : Name Field : Align  		: Left
	Local           : Field : Name Field : Width  		: 15% Page
	Local           : Field : Name Field : Invisible	: ((@@IsSales Or @@IsCreditNote) And Not ##SASpaceForInitial) Or +
																	  ((@@IsPurchase Or @@IsDebitNote) And Not ##PUSpaceForInitial) Or +
																	  ((@@IsSalesOrder Or @@IsJobOrderIn) And Not ##SOSpaceForInitial) Or +
																	  ((@@IsPurcOrder Or @@IsJobOrderOut) And Not ##POSpaceForInitial) Or +
																	  (@@IsRcptNote And Not ##RNSpaceForInitial) Or (@@IsDelNote And Not ##DNSpaceForInitial) Or +
																	  ($IsMaterialIn And Not ##RNSpaceForInitial) Or ($IsMaterialOut And Not ##DNSpaceForInitial) OR +
																	  (@@RejInvoice AND NOT ##RJInOutSpaceForInitial)
				
    Local           : Field : Short Name Field : Set as : $$LocaleString:"Verified by"
    Local           : Field : Short Name Field : Style  : Small
	Local           : Field : Short Name Field : Cells  : @@ExcelCellColumn - 10 * ($$Quotient:@@ExcelCellColumn:8)  
	Local           : Field : Short Name Field : Align  : Left
	Local           : Field : Short Name Field : Indent	: 2	
	Local           : Field : Short Name Field : Width	: 15% Page
	Local           : Field : Short Name Field : Invisible : ((@@IsSales Or @@IsCreditNote) And Not ##SASpaceForInitial) Or +
																		((@@IsPurchase Or @@IsDebitNote) And Not ##PUSpaceForInitial) Or +
																		((@@IsSalesOrder Or @@IsJobOrderIn) And Not ##SOSpaceForInitial) Or +
																		((@@IsPurcOrder Or @@IsJobOrderOut) And Not ##POSpaceForInitial) Or +
																		(@@IsRcptNote And Not ##RNSpaceForInitial) Or (@@IsDelNote And Not ##DNSpaceForInitial) Or +
																		($IsMaterialIn And Not ##RNSpaceForInitial) Or ($IsMaterialOut And Not ##DNSpaceForInitial) OR +
																		(@@RejInvoice AND NOT ##RJInOutSpaceForInitial)
				
    Local           : Field : Simple Field : Set as : $$LocaleString:"Authorised Signatory"
    Local           : Field : Simple Field : Style  : Small
	Local           : Field : Simple Field : Cells  : @@ExcelCellColumn - 8 * ($$Quotient:@@ExcelCellColumn:8)  
	Local           : Field : Simple Field : Align  : Right
	Skip Rows   	: 1

[Part:Vaibhav_Signature]
	
	Part		: Vaibhav_Signature_01
	
	;Part		: Empty
	;Local		: Part:Empty : Height: 9 mm

	Part		: Vaibhav_Signature_02
	Part		: Vaibhav_Signature_03
	Vertical	: Yes
	Border  	: Thin left
	
[Part:Vaibhav_Signature_02]
	RightPart:Vaibhav_Signature_R
	
[Part:Vaibhav_Signature_R]
	Use:Signature_Invoice


[Part: Signature_Invoice]
	Graph Type	: @@Signature_Image
	Horizontal Align:Right


	Width		: @@Signature_Width;25
	Height		: @@Signature_Height;3.5	
	
	Space Top	: @@Signature_SpaceTop
	Space Right	: @@Signature_SpaceRight
	Space Bottom: @@Signature_SpaceBottom
	

	;Width		: 50% page
	
	Lines       : EXPINV SubTitle
    Local       : Field : EXPINV SubTitle : Info    : ""
    Local       : Field : EXPINV SubTitle : Width   : 50% Page
	Local       : Field : EXPINV SubTitle : Cells   : @@ExcelCellColumn - 6 * ($$Quotient:@@ExcelCellColumn:8)
    				
[Line: Signature_Invoice]
	Field	: Signature_Invoice
			
[Field	: Signature_Invoice]
	set as : ""



[#Part: EXPSMP SignOff]
Add:Option: SimpleInvoiceCustomer_RightSignv : @@CMP_SignatureInInvoice
	
[!Part:SimpleInvoiceCustomer_RightSignv]
	Delete		: Right Parts : EXPSMP Signature
	
	Add			: Right Parts:At End:Vaibhav_Signature
	
	Local		: Part	: Vaibhav_Signature : Invisible   	: @@IsSales AND ##SACustomerSign
	Local		: Part 	: Vaibhav_Signature	: Delete		: Border
	Local		: Part 	: Vaibhav_Signature	: Local			: Part:Default : Delete:Border
	

[#Part	: EXPSMP Customer]
	Add:Option: SimpleInvoiceCustomer_RightSignv1 : @@CMP_SignatureInInvoice
	
[!Part:SimpleInvoiceCustomer_RightSignv1]
	
	Part       	: EXPINV CustomerSign
	Delete		: Right Parts : EXPSMP Signature
	
	Invisible   : NOT ##SACustomerSign
	
	Add			: Right Parts:At End:Vaibhav_Signature
	
	Local		: Part	: Vaibhav_Signature : Invisible   	: NOT ##SACustomerSign
	Local		: Part 	: Vaibhav_Signature	: Delete		: Border
	Local		: Part 	: Vaibhav_Signature	: Local			: Part:Default : Delete:Border



[System:UDF]
	EnableSignatureInInvoice 	: Logical	: 1141
	Signature_Image 			: String	: 1142

[System: formula]
	EnableSignatureInInvoice 	: $EnableSignatureInInvoice:company:##svcurrentcompany 
	
	Enable_SignatureInInvoice 	: $EnableSignatureInInvoice:voucherType:##SVVoucherType
	
	Signature_Image			 	: $Signature_Image:voucherType:##SVVoucherType
	CMP_SignatureInInvoice 		: @@EnableSignatureInInvoice AND @@Enable_SignatureInInvoice ;AND ##SA_SignaturePrint

	
[System:UDF]
	Signature_Height 		: String: 1131
	Signature_Width 		: String: 1132
	Signature_SpaceTop 		: String: 1133
	Signature_SpaceRight 	: String: 1134
	Signature_SpaceBottom 	: String: 1135

[System: formula]
	Signature_Height 		: $Signature_Height:voucherType:##SVVoucherType
	Signature_Width 		: $Signature_Width:voucherType:##SVVoucherType
	Signature_SpaceTop 		: $Signature_SpaceTop:voucherType:##SVVoucherType
	Signature_SpaceRight 	: $Signature_SpaceRight:voucherType:##SVVoucherType
	Signature_SpaceBottom 	: $Signature_SpaceBottom:voucherType:##SVVoucherType
	


[#Part: VTYP Main Left]
	Option:	vnvvoucherTypeEnableSignatureInInvoice	:	@@EnableSignatureInInvoice
	
[!Part:vnvvoucherTypeEnableSignatureInInvoice]
	add :  Parts   : At End : Enable_SignatureInInvoice
             
[Part: Enable_SignatureInInvoice]
		
	Line		: Enable_SignatureInInvoice
	Local		: Field	: LongPrompt		: Width		: @@LongWidth + 5
	
[Line: Enable_SignatureInInvoice]
	Space Top: 2 mm
	Field: Long prompt,Enable_SignatureInInvoice
	Local: Field: Long prompt : Set as: "Enable Seal & Signature In Voucher Printing ?"
	
	;Invisible: not $parent = "sales"

[Field: Enable_SignatureInInvoice]
	Use: logical field
	Storage: EnableSignatureInInvoice
	Sub Form: Signature_Location : $EnableSignatureInInvoice


[Report	: Signature_Location]
	Title	: "Seal & Signature"
	Form	: Signature_Location

[Form: Signature_Location]
	
	Part		: Signature_Location
	;Part		: Signature_Save
	
	Full Height	: No
	Full Width	: No
	
	Space Top	: 0
	Space Bottom: 0
	Background  : PurchaseVocherclr   
	Horizontal Align : Centre
	Vertical Align	 : Centre
	Option:small size form:Yes

[Part:Signature_Save]
	Line:Signature_Save
	
[Line:Signature_Save]
	RightField:Signature_Save
	
[Field:Signature_Save]
	Use:Name Field
	Read Only:Yes
	Width:3 mm

[Part: Signature_Location]
	Part: Signature_Location1
	Part: Signature_Location2
	Border:thin box

[Part: Signature_Location2]
	Part: Signature_Location11
	Part: Signature_Location22
	Vertical:Yes
	Border:thin left
	
[Part: Signature_Location11]
	Line    : Form SubTitle
	Local   : Field : Form SubTitle: Info: "Seal & Signature Preview"	
	Width	: 20% page
	
[Part: Signature_Location22]
	Graph Type	: $Signature_Image
	Width		: 20% page
	Height		: 4 cm
	
	Horizontal Align:Centre
		
	Lines       : EXPINV SubTitle
    Local       : Field : EXPINV SubTitle : Info    : "Seal & Signature"
    Local       : Field : EXPINV SubTitle : Width   : 10% Page
	Local       : Field : EXPINV SubTitle : Cells   : 1
	
[Part: Signature_Location1]
	Part: Signature_Location111
	Part: Signature_Location112
	Vertical:Yes

[Line : Signature NotesOne]
	Field 	  	 : CompanyLogoNotes
	space top : .2
	Space Bottom:.2

	Local : Field : CompanyLogoNotes: Set as      : "- " + $$LocaleString:"Formats supported are BMP and JPEG."
	
[Line : Signature NotesOne2]
	Field 	  	 : CompanyLogoNotes
	space top : .2
	Space Bottom:.2
	Local : Field : CompanyLogoNotes: Set as      : "- " + $$LocaleString:"Clear Image Use Format BMP."


[Line: Signature_Location]
	Field : medium prompt, Signature_Location
    Local : Field : medium prompt : set as 	: "Seal & Signature Location"
    Local : Field : Medium Prompt : width 	: 17
    ;space top : .2
	Space Bottom:.2
	
[Field: Signature_Location]
	Use			: Name Field
	Storage		: Signature_Image
	Set Always	: Yes
	Align		: Left
	Full Width	: Yes
	Style		: Normal bold
	Max			: 99900
	Case		: Normal
	Width		: 65
	Validation	: NOT $$IsEmpty:$$Value




[Report:Enable_SignatureLogo]
	Form:Enable_SignatureLogo


[Form:Enable_SignatureLogo]
	Part:Enable_SignatureLogo
	
	Background: PurchaseVocherClr
	
[Part:Enable_SignatureLogo]
	
	Line:Signature_Image
	;Line:SavePath

[Line:Signature_Image]
	Field: medium prompt , Signature_Image
	Local: Field:Medium Prompt : Set as: "Seal & Signature Image Path"
	Local: Field:Medium Prompt : Width : 38 mm
	Local: Field:Medium Prompt : Style: small ;bold
	
	Field: Short prompt 
	Local: Field:Short Prompt : Set as: "(Use .bmp Supported image for Seal & Signature)"
	Local: Field:Short Prompt : Width : 70 mm
	Local: Field:Short Prompt : Style: small  italic
	Local: Field:Short Prompt : Align:Centre
	Local: Field:Short Prompt : Color:blue

	Space Top	: 2 mm
	Space Bottom: 2 mm
	
[Field:Signature_Image]

	Use			: Name Field
	Storage		: Signature_Image
	Background	: white
	Border		: thin box
	Width		: 150 mm
	Max			: 250 
	Validate	: NOT $$IsEmpty:$Signature_Image
	Style		: small bold

[Line:SavePath]
	Field:  SavePath
	Space Top	: 2 mm
	Space Bottom: 2 mm
	
[Field:SavePath]
	Width		: 240 mm
	Align		: Centre
	Read Only	: Yes
	Set as		: "Save ?"
	Color		: PurchasevocherClr
	Style		: Normal bold

;;

[Part: Signature_Location111]
	Line    : Form SubTitle
	Local   : Field : Form SubTitle: Info: $$LocaleString:"Seal & Signature Location"
	
	Line	: Signature_Location
	Line	: Signature NotesOne
	Line	: Signature NotesOne2
	

[Part: Signature_Location112]
	Line    : Form SubTitle
	Local   : Field : Form SubTitle: Info: $$LocaleString:"Seal & Signature Margin"
	
	Line	: Signature_Height
	
	BottomLine:Signature_Save
	
	Local 	: Field : Medium Prompt : width 	: 6
	Local 	: Field : Short Prompt 	: width 	: 5
	Local 	: Field : Simple Prompt : width 	: 10
	Local 	: Field : Long Prompt 	: width 	: 8
	Local 	: Field : Indented Prompt : width 	: 9
	Local 	: Field : Indented Prompt : Delete	: Indent


[Line: Signature_Height]
	Field : Medium prompt, Signature_Height
	Local : Field : Medium Prompt 	: set as 	: "Height"
	
	Field : Short prompt, Signature_Width
    Local : Field : Short Prompt 	: set as 	: "Width"
	
	Field : Long prompt, Signature_SpaceTop
	Local : Field : Long Prompt 	: set as 	: "Space Top"
	
	Field : Indented prompt, Signature_SpaceRight
    Local : Field : Indented Prompt : set as 	: "Space Right"
	
	Field : Simple prompt, Signature_SpaceBottom
    Local : Field : Simple Prompt 	: set as 	: "Space Bottom"
	
	Space Bottom:.2
		
[Field: Signature_Height]
	Use			: Name Field
	Storage		: Signature_Height
	Width		: 15 mm
	Border		: Thin Box
	Background	: White
    Set as		: "3.5"
	Align		: Centre
	
[Field: Signature_Width]
	Use			: Name Field
	Storage		: Signature_Width
	Width		: 15 mm
	Border		: Thin Box
	Background	: White
	Set as		: "25"
	Align		: Centre
	
[Field: Signature_SpaceTop]
	Use			: Name Field
	Storage		: Signature_SpaceTop
	Width		: 15 mm
	Border		: Thin Box
	Background	: White
	Set as		: "0.1"
	Align		: Centre
	
[Field: Signature_SpaceRight]
	Use			: Name Field
	Storage		: Signature_SpaceRight
	Width		: 15 mm
	Border		: Thin Box
	Background	: White
	Align		: Centre
	Set as		: "0.5"
	
[Field: Signature_SpaceBottom]
	Use			: Name Field
	Storage		: Signature_SpaceBottom
	Width		: 15 mm
	Border		: Thin Box
	Background	: White
	Align		: Centre
	Set as		: "0.1"
	


;;Payment / Receipt
[#Form: NormalPRPrint]
	Add:Option: Payment_RightSign : @@CMP_SignatureInInvoice
	
[!Form:Payment_RightSign]
	Add:Bottom Part:Before:PPR Sign : Payment_Signature
	
[Part:Payment_Signature]
	RightPart:Signature_Invoice
	Space Top   : 0.75 inch
	
[#Part: PPR Sign]
	Add:Option: Payment_RightSign : @@CMP_SignatureInInvoice
	
[!Part:Payment_RightSign]
	Delete		: Space Top   : 0.75 inch
    
;;Journal Print
[#Form: NormalJRPrint]
		Add:Option: Journal_RightSign : @@CMP_SignatureInInvoice
	
[!Form:Journal_RightSign]
	Add:Bottom Part:Before:PJR Sign : Payment_Signature

[#Part: PJR Sign]
	Add:Option: Journal_RightSign : @@CMP_SignatureInInvoice
	
[!Part:Journal_RightSign]
   Delete		: Space Top   : 0.75 inch
   
